計算格子の出力

CGNSファイルに、計算格子を出力します。

ソルバーでは、ソルバーで計算に用いる格子を生成する場合や、 2次元格子から3次元格子を生成する場合に行います。

格子生成プログラムでは必ず行います。

ここで示す関数は、ソルバーでは計算開始時の格子を出力するために使用します。 計算中に格子形状が変化する場合の格子の出力には、計算格子の出力 (計算開始後の格子) に示す関数を使用して下さい。

表 66 利用する関数
関数 備考
cg_iric_write_grid1d_coords 1次元構造格子を出力する
cg_iric_write_grid2d_coords 2次元構造格子を出力する
cg_iric_write_grid3d_coords 3次元構造格子を出力する
cg_iric_write_grid_real_node 格子点で定義された整数の属性を出力する
cg_iric_write_grid_integer_node 格子点で定義された倍精度実数の属性を出力する
cg_iric_write_grid_real_cell セルで定義された整数の属性を出力する
cg_iric_write_grid_integer_cell セルで定義された倍精度実数の属性を出力する

2次元格子を読み込み、それを分割して生成した3次元格子を 出力する処理の記述例を リスト 99 に示します。

リスト 99 3次元格子を出力する処理の記述例
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
program Sample7
  use iric
  implicit none

  integer:: fin, ier, isize, jsize, ksize, i, j, k, aret
  double precision:: time
  double precision:: convergence
  double precision, dimension(:,:), allocatable::grid_x, grid_y, elevation
  double precision, dimension(:,:,:), allocatable::grid3d_x, grid3d_y, grid3d_z
  double precision, dimension(:,:,:), allocatable:: velocity, density

  ! CGNS ファイルのオープン
  call cg_iric_open('test3d.cgn', IRIC_MODE_MODIFY, fin, ier)
  if (ier /=0) STOP "*** Open error of CGNS file ***"

  ! 格子のサイズを調べる
  call cg_iric_read_grid2d_str_size(fin, isize, jsize, ier)
  ! 格子を読み込むためのメモリを確保
  allocate(grid_x(isize,jsize), grid_y(isize,jsize), elevation(isize,jsize))
  ! 格子を読み込む
  call cg_iric_read_grid2d_coords(fin, grid_x, grid_y, ier)
  call cg_iric_read_grid_real_node(fin, 'Elevation', elevation, ier)

  ! 読み込んだ2次元格子を元に、3次元格子を生成。
  ! 3次元格子は Z方向に、深さ 5 で、5分割する

  ksize = 6
  allocate(grid3d_x(isize,jsize,ksize), grid3d_y(isize,jsize,ksize), grid3d_z(isize,jsize,ksize))
  allocate(velocity(isize,jsize,ksize), STAT = aret)
  print *, aret
  allocate(density(isize,jsize,ksize), STAT = aret)
  print *, aret
  do i = 1, isize
    do j = 1, jsize
      do k = 1, ksize
        grid3d_x(i,j,k) = grid_x(i,j)
        grid3d_y(i,j,k) = grid_y(i,j)
        grid3d_z(i,j,k) = elevation(i,j) + (k - 1)
        velocity(i,j,k) = 0
        density(i,j,k) = 0
      end do
    end do
  end do
  ! 生成した3次元格子を出力
  call cg_iric_write_grid3d_coords(fin, isize, jsize, ksize, grid3d_x, grid3d_y, grid3d_z, ier)

  ! 初期状態の情報を出力
  time = 0
  convergence = 0.1
  call cg_iric_write_sol_start(fin, ier)
  call cg_iric_write_sol_time(fin, time, ier)
  ! 格子を出力
  call cg_iric_write_sol_grid3d_coords(fin, grid3d_x, grid3d_y, grid3d_z, ier)
  ! 計算結果を出力
  call cg_iric_write_sol_node_real(fin, 'Velocity', velocity, ier)
  call cg_iric_write_sol_node_real(fin, 'Density', density, ier)
  call cg_iric_write_sol_baseiterative_real(fin, 'Convergence', convergence, ier)
  call cg_iric_write_sol_end(fin, ier)

  do
    time = time + 10.0
    ! (ここで計算を実行。格子の形状も変化)
    call cg_iric_write_sol_start(fin, ier)
    call cg_iric_write_sol_time(fin, time, ier)
    ! 格子を出力
    call cg_iric_write_sol_grid3d_coords(fin, grid3d_x, grid3d_y, grid3d_z, ier)
    ! 計算結果を出力
    call cg_iric_write_sol_node_real(fin, 'Velocity', velocity, ier)
    call cg_iric_write_sol_node_real(fin, 'Density', density, ier)
    call cg_iric_write_sol_baseiterative_real(fin, 'Convergence', convergence, ier)
    call cg_iric_write_sol_end(fin, ier)

    If (time > 100) exit
  end do

  ! CGNS ファイルのクローズ
  call cg_iric_close(fin, ier)
  stop
end program Sample7